Testing WIFI modules

Espressif ESP8266

A flood of ESP8266 based WiFi modules are hitting the DIY hobby markets. The ESP8266 provides 802.1 b/g/n WiFi and includes embedded TCP/IP stack. The ESP8266 itself provide many peripheral devices, if you have the SDK and programming means. But the available modules only communicate using logic level RS232 AT+ command set. Currently the AT+ command set is incomplete, inconsistant, in flux, and sparsley documented. Yet, that can be worked around for those wanting to get a head start using these very inexpensive modules.

There are several module designs called ESP-x where x is 1 to 5, so far. I am using the ESP-1 module of which there are two versions. The older one is set at 57600 baud. The newer one is set at 115200 baud. The older one provides a 2x4 connector with 3v3, GND, TX, RX, and 4 NC (No Connects). The newer one provides the same 2x4 connector, but has connected the NCs to RST, CH_DP(chip enable), and two GPIOs, GPIO0 and GPIO2. Make sure you pullup the CH_DP and the RST line. They are finacky. So far it seems you can leave the GPIOs floating. The documentation is sparse. The firmware is in flux. Eventually, you should know how to use the GPIOs and how to use them along with the CH_DP and RST line to program the ESP8266 directly. In the meantime, you have to use the available AT commands.

Older Version

Newer Version

The ESP8266 is advertized as a ULP WiFi solution. Perhaps, while it is sleeping, but when being used it draws an average of 80mA. Sometimes it can draw as much as 300mA. So do not connect to a whimpy 3v3 supply. That includes many USB ports, and 100mA regulator circuits. It may seem to work for a short while and then something glitches. The modules firmware seems to be finacky as it is still being developed.. as far as I can tell.

My first project with this chip is to provide a telnet like daemon to access a menu. No login, no security, just testing. This sketch controls the RGB LEDs on the RFduino LED shield. It needs a lot of work to clean it up. But hopefully gives a an idea what is involved.

myESP23srviceV0.1.ino myESP23serviceV0.1.ino

// ESP8266 WIFI Server on RFduino
// by Thomas Olson
// teo201409021.01
// teo201409027.01 // found strlen error
//
// Testing ESP8266 ESP-1 WIFI Module with RFduino
// My modules are Firmware Version 00150900
// This firmware version only runs at 115200 baud. it seems.
// This test code doesn't have much in way of error checking, and
// there seems a lot of errors can happen with this module.
// Not ready for prime time. Still some quarky stuff going on.
/*
ESP-1  <-> RFduino
RX      TX (1)
TX      RX (0)
GND    GND
3V3 - DO NOT use whimpy 3V supplies; needs 80mA avg, 300mA sometimes
CH_DP - pullup to 3v3
RST - pullup to 3v3
GPIO2 - no connect for now
GPIO0 - no connect for now
*/
// Simple text based command service - essentially dumb telnetd
// without any login or security features. no file system.

#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include <itoa.h>

#define myVERSION "ver 0.1.1\r\n"
char menu[] = "Here is help:\r\n hH? - Help\r\n Pp - get IP\r\n Rr - red LED ON/OFF\r\n Gg - green LED ON/OFF\r\n Bb - blue LED ON/OFF\r\n Ii - misc info status\r\n Vv - Version\r\n";

// WIFI stuff
#define SSID  "YOUR_SSID" // your network SSID
#define PASS  "YOUR_PASSWD"  // your AP or router password
#define PORT  "23"          // desired service port (23=telnet)
char myIP[18] = "0.0.0.0"; // get it from module which gets from DHCP
bool wifiModPresent = 0;
bool wifiReady = 0;
bool wifiConnected = 0;

int LED_RED = 2;
int LED_GREEN = 3;
int LED_BLUE = 4;


void setup() {
  pinMode(LED_RED, OUTPUT);
  pinMode(LED_GREEN, OUTPUT);
  pinMode(LED_BLUE, OUTPUT);
  
  Serial.begin(115200);
  Serial.setTimeout(2000);
//  delay(2000); // give me time to start serial monitor

  digitalWrite(LED_RED,0);
  digitalWrite(LED_GREEN,0);
  digitalWrite(LED_BLUE,0);

  // Of course if we got the ready, we know we have access to
  // the module. But doing a simple AT will verify it again.
  
  while(!wifiModPresent){
    wifiMod(); // see if we get response from basic AT command
    delay(1000);
  }
  
  // setup service.
  setupTCPservice();
//  wifiConnected = 1;
}

void loop() {

  
  if(wifiConnected){
    char recvBuf[128];

    bzero(recvBuf,128);
    Serial.flush();
    Serial.readBytesUntil('\n',recvBuf,128);

    switch (recvBuf[0]){
      case 'r':
      case 'l':
      case 'u':
      case 'O':
        // probably initial ready,link,unlink,OK 
        break;
      case '+':
        // probably +IPD, which is what we want
        decodeIPDpacket(recvBuf);
        break;
      default:
        break;
    } //switch()    

  // toggle the GREEN LED after receipt or timeout
  //digitalWrite(LED_GREEN, 1);
  //delay(100);
  //digitalWrite(LED_GREEN, 0);
  //delay(100);
  
  } //if()

} //loop()


void decodeIPDpacket(char *recvBuf){
int ch,len;
char cmd[128]; // currently not expecting more than 128 bytes.
    // assumes +IPD, was received at beginning of recvBuf.
    bzero(cmd,128);
    sscanf(&recvBuf[5],"%d,%d:%s",&ch,&len,cmd);
      if(len > 128)len=128;
      cmd[len] = 0;

      switch (cmd[0]){
        case '?':
        case 'h':
        case 'H':
          // Help menu 
          espSend(ch,menu);
          delay(10);
          break;
        case 'r':
          // turn RED LED OFF
          digitalWrite(LED_RED,0);
          espSend(ch,"red LED off\r\n");
          break;
        case 'R':
          // turn RED LED ON
          digitalWrite(LED_RED,1);
          espSend(ch,"red LED on\r\n");
          break;
        case 'b':
          // turn BLUE LED OFF
          digitalWrite(LED_BLUE,0);
          espSend(ch,"blue LED off\r\n");
          break;
        case 'B':
          // turn BLUE LED ON
          digitalWrite(LED_BLUE,1);
          espSend(ch,"blue LED on\r\n");
          break;
        case 'g':
          // turn GREEN LED OFF
          digitalWrite(LED_GREEN,0);
          espSend(ch,"green LED off\r\n");
          break;
        case 'G':
          // turn GREEN LED ON
          digitalWrite(LED_GREEN,1);
          espSend(ch,"green LED on\r\n");
          break;
        case 'V':
        case 'v':
          espSend(ch,myVERSION);
          break;
        case 'i':
        case 'I':
          //Serial.println("Info Requested");
          if(wifiModPresent) espSend(ch,"wifiModPresent=1\r\n");
          if(wifiReady) espSend(ch,"wifiReady=1\r\n");
          if(wifiConnected) espSend(ch,"wifiConnected=1\r\n");
          break;
        case 'p':
        case 'P':
          // fetch IP address
          espSend(ch,"myIP is: NOT IMPLEMENTED\r\n");
          break;
        case 'm':
        case 'M':
          wifiMod();
          if(wifiModPresent) espSend(ch,"wifiModPresent=1\r\n");
          break;
        default:
          espSend(ch,"unknown command\r\n");
          break;
      }
      
      delay(10);
      espSend(ch,"\r\nRFduinoESP:~ # ");
}

bool espSend(int ch, char *packet){
char packetLen[20];
  bzero(packetLen,20);
  itoa(strlen(packet),packetLen,10);
//  Serial.setTimeout(5000);
  Serial.print("AT+CIPSEND="); // send command
  Serial.print(ch);
  Serial.print(',');
//  Serial.println(strlen(packet));
  Serial.println(packetLen);
  if(Serial.find(">")){        // wait for > to send data.
    Serial.print(packet);
    delay(20);
    return 1;
  }else{
    delay(20);
    return 0;
  }
}

// See if WiFi Module is present. Should respond to AT with OK.
void wifiMod(){
delay(10);  
  Serial.print("AT\r\n");
  if(Serial.find("OK")){
    wifiModPresent = 1;
//    digitalWrite(LED_BLUE,1); 
  }else{
    wifiModPresent = 0;
  }
}
 
// I tested my ESP-1 using a serial monitor and it seems to
// remember some things. So don't really need to redo it again.
void wifiReset(){
  Serial.setTimeout(5000);  
  Serial.print("AT+RST\r\n"); // Reset the ESP8266
  delay(10);
  if(Serial.find("ready")){
    wifiReady = 1;
  }else{
    wifiReady = 0;
  }
}

// Again, the module seems to remember it's connection information
// so don't really need to do it again if not mobile. Watching my
// dhcp logs the module gets a IP all by itself. In my case that
// means it already made it's way through the AP authentication.
void wifiConnect(){
  // connect to WIFI AP(Access Point) or Router
  Serial.print("AT+CWMODE=3\r\n"); //
  delay(10);
//  Serial.flush();
  Serial.print("AT+CWJAP=\"");
  Serial.print(SSID);
  Serial.print("\",\"");
  Serial.print(PASS);
  Serial.print("\"\r\n");
  if(Serial.find("OK")){
    wifiConnected = 1;
    digitalWrite(LED_GREEN,1);
  }else{
    wifiConnected = 0;
  }
}

void setupTCPservice(){
//  wifiMod(); // I do this in setup already
//  wifiReset(); // perhaps not needed as is done on powerup.
  wifiConnect(); // perhaps only needed once.    
  
  // setup Service
  Serial.print("AT+CIPMUX=1\r\n"); // allow multiple connections
  if(Serial.find("OK")){
    digitalWrite(LED_RED,1);
  }
  Serial.print("AT+CIPSERVER=1,"); // turn on TCP service
  Serial.print(PORT);              // on PORT number
  Serial.print("\r\n");
  delay(1000); // delay then turn off LEDs
  digitalWrite(LED_RED,0);
  digitalWrite(LED_GREEN,0);
  digitalWrite(LED_BLUE,0);
}

Using port 80 one can do the same thing using HTML pages.

It is also fairly easy to send datalogging information to IoT services like ThingSpeak to be shared with others.

Other RFduino Projects